# Computing derivatives in Julia


{{< include ../_common_code.qmd >}}

This section uses these add-on packages:


```{julia}
using CalculusWithJulia
using Plots
plotly()
using ForwardDiff
using SymPy
using Roots
```


---


`SymPy` returns symbolic derivatives. Up to choices of simplification, these answers match those that would be derived by hand. This is useful when comparing with known answers and for seeing the structure of the answer. However, there are times we just want to work with the answer numerically. For that we have other options within `Julia`. We discuss approximate derivatives and automatic derivatives in this section. The latter will find wide usage in these notes.


## Approximate derivatives


By approximating the limit of the secant line with a value for a small, but positive, $h$, we get an approximation to the derivative. That is


$$
f'(x) \approx \frac{f(x+h) - f(x)}{h}.
$$

This is the *forward-difference approximation*. The *central difference approximation* looks to both sides of $x$:


$$
f'(x) \approx \frac{f(x+h) - f(x-h)}{2h}.
$$

Though in general they are different, both are easy and fast to compute, useful approximations to the derivative. The central difference is usually more accurate for the same size $h$. However, both are susceptible to round-off errors. The numerator is a subtraction of like-size numbers---a perfect opportunity to lose precision.


Due to numeric issues there is a balancing act:

* if $h$ is too big the approximation to the limit is not good.

* if $h$ is too small the round-off errors are problematic,



For the forward difference $h$ values around $10^{-8}$ are typically good, for the central difference, values around $10^{-6}$ are typically good, but these ranges aren't always the case.


##### Example


Let's verify that the forward difference isn't too far off.


```{julia}
f(x) = exp(-x^2/2)
c = 1
h = 1e-8
fapprox = (f(c+h) - f(c)) / h
```

We can compare to the actual with:


```{julia}
@syms x
df = diff(f(x), x)
factual = convert(Float64, df(c))
abs(factual - fapprox)
```

The error is about $1$ part in $100$ million.


The central difference is better here, even with a bigger $h$:^[The [FiniteDifferences](https://github.com/JuliaDiff/FiniteDifferences.jl) and [FiniteDiff](https://github.com/JuliaDiff/FiniteDiff.jl) packages provide performant interfaces for differentiation based on finite differences.]


```{julia}
#| hold: true
h = 1e-6
cdapprox = (f(c+h) - f(c-h)) / (2h)
abs(factual - cdapprox)
```


### Automatic derivatives

Roughly speaking, symbolic derivatives are exact, but can be slow to compute, whereas approximate derivatives are not exact, but fast to compute. However, the widely used automatic derivatives are both exact and fast to compute.

Automatic differentiation (AD) is the general name for a few different approaches. We utilize forward mode automatic differentiation. The `ForwardDiff` package provides one of [several](https://juliadiff.org/) ways for `Julia` to compute automatic derivatives. `ForwardDiff` is well suited for functions encountered in these notes, which depend on at most a few variables and output no more than a few values at once.

The `ForwardDiff` package was loaded in this section; in general its features are available when the `CalculusWithJulia` package is loaded, as that package provides a more convenient interface. The `derivative` function is not exported  by `ForwardDiff`, so its usage requires qualification. To illustrate, to find the derivative of $f(x)$ at a *point* we have this syntax for `ForwardDiff`:


```{julia}
ForwardDiff.derivative(f, c)   # derivative is qualified by a module name
```


The `CalculusWithJulia` package defines a method for `'` (a postfix operator in `Julia`) so that when applied to a `Function` object a function for computing values of the derivative, as above, is returned.^[The `CalculusWithJulia` package defines a method for `Base.adjoint(f::Function)`. In `Julia` speak this is a form of *type piracy*, as the package modifies a method (`adjoint`) for a type (`Function`) neither of which belongs to the package. As well, the meaning given does not conform with the expected generic meaning of the operation elsewhere in the `Julia` ecosystem. Admittedly this is bad form, but a useful deviation from good practice for pedagogical reasons.]


To be clear, this usage returns a function that computes the derivative of `f`:

```{julia}
f'
```

And this usage *calls* the derivative of `f` at the value stored by `c`:

```{julia}
f'(c)
```

This is the same mathematical notation that is commonly used.

Here we see the error in estimating $f'(1)$:


```{julia}
abs(factual - f'(c))
```

In this case, the automatic derivative is exact.



##### Example


For $f(x) = \sqrt{1 + \sin(\cos(x))}$ compare the difference between the forward derivative with $h=1e-8$ and that computed by automatic differentiation at $x=\pi/4$.


The forward derivative is found with:


```{julia}
f(x) = sqrt(1 + sin(cos(x)))
c, h = pi/4, 1e-8
fwd = (f(c+h) - f(c))/h
```

That given by automatic differentiation is:


```{julia}
ds_value = f'(c)
ds_value, fwd, ds_value - fwd
```

Finally, `SymPy` gives an exact value we use to compare:


```{julia}
fp = diff(f(x), x)
```

```{julia}
actual = float(fp(PI/4))
actual - ds_value, actual - fwd
```

As expected, the automatic derivative is nearly exact and accurate up to possibly accumulated floating point differences; the forward difference is just pretty close.

##### Example


Suppose our task is to find a zero of the second derivative of $k(x) = e^{-x^2/2}$ in $[0, 10]$, a known bracket. The second derivative is found by `k''` below, with the derivative operation being applied twice behind the scenes. With this, we have:


```{julia}
#| hold: true
k(x) = exp(-x^2/2)
find_zero(k'', (0, 10))
```

As with plotting and other uses of functions as arguments, we pass in the function object, `k''`, and not the function evaluated at a point.


## Recap on derivatives in Julia


A quick summary of the $3$ different ways for finding derivatives in `Julia` presented in these notes:

* Symbolic derivatives are found using `diff` from `SymPy`

* Automatic derivatives are found using the notation `f'` which utilizes `ForwardDiff.derivative`

* approximate derivatives at a point, `c`, for a given `h` are found with `(f(c+h)-f(c))/h`.


For example, here all three are computed and compared:


```{julia}
#| hold: true
f(x) = exp(-x) * sin(x)

c = pi
h = 1e-8

fp = diff(f(x),x)

Dict(:approximate=>(f(c+h) - f(c))/h, :automatic=>f'(c),
     :symbolic=>fp, :symbolic_evaluated => fp(x=>c))
```


## Questions


###### Question


Find the derivative using a forward difference approximation of $f(x) = x^x$ at the point $x=2$ using `h=0.1`:


```{julia}
#| hold: true
#| echo: false
f(x) = x^x
c, h = 2, 0.1
val = (f(c+h) - f(c))/h
numericq(val)
```

Use `f'` find the value using automatic differentiation


```{julia}
#| hold: true
#| echo: false
f(x) = x^x
c = 2
val = f'(c)
numericq(val)
```


###### Question


Let $f(x) = x^x$. Using automatic differentiation, find $f'(3)$.


```{julia}
#| hold: true
#| echo: false
f(x) = x^x
val = D(f)(3)
numericq(val)
```

###### Question


Let $f(x) = \lvert 1 - \sqrt{1 + x}\rvert$. Using automatic differentation, find $f'(3)$.


```{julia}
#| hold: true
#| echo: false
f(x) = abs(1 - sqrt(1 + x))
val = D(f)(3)
numericq(val)
```

###### Question


Let $f(x) = e^{\sin(x)}$. Using automatic differentation, find $f'(3)$.


```{julia}
#| hold: true
#| echo: false
f(x) = exp(sin(x))
val = D(f)(3)
numericq(val)
```

###### Question


For `Julia`'s `airyai` function find a numeric derivative using the forward difference. For $c=3$ and $h=10^{-8}$ find the forward difference approximation to $f'(3)$ for the `airyai` function.


```{julia}
#| hold: true
#| echo: false
h = 1e-8
c = 3
val = (airyai(c+h) - airyai(c))/h
numericq(val)
```

###### Question


Find the rate of change with respect to time of the function $f(t)= 64 - 16t^2$ at $t=1$.


```{julia}
#| hold: true
#| echo: false
fp_(t) = -16*2*t
c = 1
numericq(fp_(c))
```

###### Question


Find the rate of change with respect to height, $h$, of $f(h) = 32h^3 - 62 h + 12$ at $h=2$.


```{julia}
#| hold: true
#| echo: false
fp_(h) = 3*32h^2 - 62
c = 2
numericq(fp_(2))
```


###### Question


Mathematically, as the value of `h` in the forward difference gets smaller the forward difference approximation gets better. On the computer, this is thwarted by floating point representation issues (in particular the error in subtracting two like-sized numbers in forming $f(x+h)-f(x)$.)


For `1e-16` what is the error (in absolute value) in finding the forward difference approximation for the derivative of $\sin(x)$ at $x=0$?


```{julia}
#| hold: true
#| echo: false
f(x) = sin(x)
h = 1e-16
c = 0
approx = (f(c+h)-f(c))/h
val = abs(cos(c)  - approx)
numericq(val)
```

Repeat for $x=\pi/4$:


```{julia}
#| hold: true
#| echo: false
f(x) = sin(x)
h = 1e-16
c = pi/4
approx = (f(c+h)-f(c))/h
val = abs(cos(c)  - approx)
numericq(val)
```


##### Question

Let $f(x) = e^{-x^2/2}$. At $c=2$ we can compare the exact answer for the derivative to the forward difference approximation for different values of `h`. For example:

```{julia}
f(x) = exp(-x^2/2)
c = 2
@syms x
exact = float(diff(f(x), x)(x=>2))
```

Whereas,

```{julia}
hs = [1/10^i for i in 0:16]
fdiffs = [(f(c+h) - f(c))/h for h in hs]
error = fdiffs .- exact
[hs error]
```

Which value of `h` provided the smallest error? Write the exponent as `i` in `1/10^i`.

```{julia}
#| echo: false
numericq(8)
```


We repeat with the central difference approximation.

```{julia}
hs = [1/10^i for i in 0:16]
cdiffs = [(f(c+h) - f(c-h))/(2h) for h in hs]
error = cdiffs .- exact
[hs error]
```

Which value of `h` provided the smallest error? Write the exponent as `i` in `1/10^i`.

```{julia}
#| echo: false
numericq(6)
```
